training wan 2.2 loras on 5070TI 16gb

my 5070 trains 2.1 loras fine with an average of 4 to 6 iterations, depending on the dataset can do a full train in 1 to 1.5 hours. In wan 2.2 I haven't been able to tweak the training to run with a reasonable it/s rate 80>120 which puts it at 3 or so days for a full train. I have seen posts of other people successful with my setup curious is anyone here has trained on similiar hardware and if so what is your training configuration? I'm using musubi-tuner and here is my training batch file. I execute it train.bat high <file.toml> this way i can use the batch file for high and low. claud is recommending me swap to BF16 but search as hard as I can can't find a high and low BF16 file. I have found bf16 transformers but they are multi file repository which won't work for musibi.

echo off

title gpu0 musubi

setlocal enabledelayedexpansion

REM --- Validate parameters ---

if "%~1"=="" (

echo Usage: %~nx0 [high/low] [config.toml]

pause

exit /b 1

)

if "%~2"=="" (

echo Usage: %~nx0 [high/low] [config.toml]

pause

exit /b 1

)

set "MODE=%~1"

if /i not "%MODE%"=="high" if /i not "%MODE%"=="low" (

echo Invalid parameter: %MODE%

echo First parameter must be: high or low

pause

exit /b 1

)

set "CFG=%~2"

if not exist "%CFG%" (

echo Config file not found: %CFG%

pause

exit /b 1

)

set "WAN=D:\github\musubi-tuner"

set "DIT_LOW=D:\comfyui\ComfyUI\models\diffusion_models\wan2.2_t2v_low_noise_14B_fp16.safetensors"

set "DIT_HIGH=D:\comfyui\ComfyUI\models\diffusion_models\wan2.2_t2v_high_noise_14B_fp16.safetensors"

set "VAE=D:\comfyui\ComfyUI\models\vae\Wan2.1_VAE.pth"

set "T5=D:\comfyui\ComfyUI\models\clip\models_t5_umt5-xxl-enc-bf16.pth"

set "OUT=D:\DATA\training\wan_loras\tammy_v2"

set "OUTNAME=tambam"

set "LOGDIR=D:\github\musubi-tuner\logs"

set "CUDA_VISIBLE_DEVICES=0"

set "PYTORCH_ALLOC_CONF=expandable_segments:True"

REM --- Configure based on high/low ---

if /i "%MODE%"=="low" (

set "DIT=%DIT_LOW%"

set "TIMESTEP_MIN=0"

set "TIMESTEP_MAX=750"

set "OUTNAME=%OUTNAME%_low"

) else (

set "DIT=%DIT_HIGH%"

set "TIMESTEP_MIN=250"

set "TIMESTEP_MAX=1000"

set "OUTNAME=%OUTNAME%_high"

)

echo Training %MODE% noise LoRA

echo Config: %CFG%

echo DIT: %DIT%

echo Timesteps: %TIMESTEP_MIN% - %TIMESTEP_MAX%

echo Output: %OUT%\%OUTNAME%

cd /d "%WAN%"

accelerate launch --num_processes 1 "wan_train_network.py" ^

--compile ^

--compile_backend inductor ^

--compile_mode max-autotune ^

--compile_dynamic auto ^

--cuda_allow_tf32 ^

--dataset_config "%CFG%" ^

--discrete_flow_shift 3 ^

--dit "%DIT%" ^

--fp8_base ^

--fp8_scaled ^

--fp8_t5 ^

--gradient_accumulation_steps 4 ^

--gradient_checkpointing ^

--img_in_txt_in_offloading ^

--learning_rate 2e-4 ^

--log_with tensorboard ^

--logging_dir "%LOGDIR%" ^

--lr_scheduler cosine ^

--lr_warmup_steps 30 ^

--max_data_loader_n_workers 16 ^

--max_timestep %TIMESTEP_MAX% ^

--max_train_epochs 70 ^

--min_timestep %TIMESTEP_MIN% ^

--mixed_precision fp16 ^

--network_args "verbose=True" "exclude_patterns=[]" ^

--network_dim 16 ^

--network_alpha 16 ^

--network_module networks.lora_wan ^

--optimizer_type AdamW8bit ^

--output_dir "%OUT%" ^

--output_name "%OUTNAME%" ^

--persistent_data_loader_workers ^

--save_every_n_epochs 2 ^

--seed 42 ^

--t5 "%T5%" ^

--task t2v-A14B ^

--timestep_boundary 875 ^

--timestep_sampling sigmoid ^

--vae "%VAE%" ^

--vae_cache_cpu ^

--vae_dtype float16 ^

--sdpa

if %ERRORLEVEL% NEQ 0 (

echo.

echo Training failed with error code %errorlevel%

)

pause